Space Shuttle - The First 100 Flights/Space Shuttle - The First 100 Flights.iso/xTras/DirectMedia Xtra Behaviors.cst/00009_Script_Rate slider

Text File | 2000-01-16 | 6KB | 169 lines

-- DirectMedia Xtra Rate Slider




property pDuration, pMovieTime, VideoSprite

property extentSprite
property hiliteMember  -- looks like the handle plus hilite graphics
-- also holds the member of handle while hilited

property tracking
property newLocH
property newLocV

property dynamic   -- if true and sending true, sends value while tracking

property min, max  -- the range the slider maps to
property valrange  -- the difference of max and min, set on begin
property minScreen, maxScreen -- calculated from the screen coords of the extent
property currentScreenVal -- the data point in screen coords, set in tracking
property extentlength -- in screen coords, set on begin

property CurrentVal

on getPropertyDescriptionList
  if the currentspritenum = 0 then
    set memdefault = 0
  else
    set memref = the member of sprite the currentspritenum
    set castlibnum = the castlibnum of memref
    set memdefault = member (the membernum of member memref + 1)
  end if


  set description = [:]

  addprop description, #VideoSprite, [#default: 1, #format:#integer, #comment: "Video Sprite:"]

  addprop description, #extentSprite, [#default: 1, #format:#integer, #comment: "Extent Sprite:"]

  addprop description, #hiliteMember, [#default: memdefault , #format:#graphic,#comment: "Hilite Member:"]

  addprop description, #dynamic, [#default: 1, #format:#boolean,#comment: "Dynamic:"]

  return description
end

on getBehaviorDescription
  return "Drag to slider 'handle' to enable control of video rate.  Requires additional 'extent' member which limits the handle travel range." & RETURN & "PARAMETERS:" & RETURN & "ò Video Sprite - Enter the number of sprite channel in which video is displayed." & RETURN & "ò Extent Sprite -  Enter the number of sprite channel that contains the 'extent' sprite."  & RETURN & "ò Hilite Member -  Member to display while handle is being dragged."  & RETURN & "ò Dynamic - If set, video time will be updated while handle is dragged, else when handle is released."
end

on compute_val me
  -- relies on tracking to update the currentScreenVal (different for Hor, Vert)
  set val = 0.0
  set val = float(the currentScreenVal of me) / float (the extentlength of me)
  set val = val * the valrange of me
  set val = val + the min of me
  return val
end

on send_the_val me, val
  -- sets the digital video volume to the val * paramter
  set pMovieTime = val * pDuration
  setrate(sprite VideoSprite, pMovieTime)
end


on beginSprite me

  set pDuration = 200

  set the min of me = 0.0
  set the max of me = 1.0

  set handle = the spritenum of me
  set the tracking of me = FALSE
  set the newLocH of me = the locH of sprite handle
  set the newLocV of me = the locV of sprite handle

    set the newLocV of me = the locV of sprite the extentSprite of me
    set the minScreen of me = the left of sprite the extentSprite of me
    set the maxScreen of me = the right of sprite the extentSprite of me

  set the locH of sprite handle to the newLocH of me
  set the locV of sprite handle to the newLocV of me

  set the valrange of me = the max of me - the min of me
  set the extentlength of me = the maxScreen of me - the minScreen of me

end

on prepareFrame me
  -- limits motion of handle to extents of extentSprite
  -- and locks the handle to the track of the extentSprite

  if tracking then
    set handle = the spriteNum of me
    set extent =  the extentSprite of me

      set the newLocH of me = the mouseH
      set the newLocV of me = the locV of sprite extent
      if the newLocH of me < the left of sprite extent then
        set the newLocH of me = the left of sprite extent
      end if
      if the newLocH of me > the right of sprite extent then
        set the newLocH of me = the right of sprite extent
      end if

      set the currentScreenVal of me = the newLocH of me - the minScreen of me

    set the locH of sprite handle to the newLocH of me
    set the locV of sprite handle to the newLocV of me

    if the dynamic of me then
      send_the_val me, compute_val (me)
    end if

  else   --  end if tracking, control slider position by movieTime

    set x = float(getrate(sprite VideoSprite))/ float(pDuration)

    set handle = the spriteNum of me
    set extent =  the extentSprite of me

      set ScreenX = the left of sprite extent + (x * (the right of sprite extent - the left of sprite extent))
      set the newLocH of me = screenX
      set the newLocV of me = the locV of sprite extent
      if the newLocH of me < the left of sprite extent then
        set the newLocH of me = the left of sprite extent
      end if
      if the newLocH of me > the right of sprite extent then
        set the newLocH of me = the right of sprite extent
      end if

      set the currentScreenVal of me = the newLocH of me - the minScreen of me

    set the locH of sprite handle to the newLocH of me
    set the locV of sprite handle to the newLocV of me

  end if
end

on mouseDown me
  set tracking = TRUE
  set temp = the member of sprite the spritenum of me
  set the member of sprite the spritenum of me = member the hiliteMember of me
  set the hiliteMember of me = temp
end

on mouseUp me
  set tracking = FALSE
  set temp = the member of sprite the spritenum of me
  set the member of sprite the spritenum of me = member the hiliteMember of me
  set the hiliteMember of me = temp

end

on mouseUpOutside me
  set tracking = FALSE
  set temp = the member of sprite the spritenum of me
  set the member of sprite the spritenum of me = member the hiliteMember of me
  set the hiliteMember of me = temp

end